...auf Radiobuttons im TWebbrowser zugreifen?

procedure TForm1.Button1Click(Sender: TObject);
var
  Document: IHTMLDocument2;
  rbTestList: IHTMLElementCollection;
  rbTest: IHTMLOptionButtonElement;
  I: Integer;
begin
  // Get a reference to the document
  // Referenz auf Dokument
  Document := WebBrowser1.Document as IHTMLDocument2;

  // Get a reference to input-control (Radiobutton)
  // Referenz auf Eingabe-Control-Element (Radiobutton)
  rbTestList := Document.all.item('rating', EmptyParam) as IHTMLElementCollection;

  // Get current values.
  // Aktuellen Wert auslesen
  for I := 0 to rbTestList.Length - 1 do
  begin
    // reference to the i. RadioButton
    // Referenz auf i. RadioButton
    rbTest := rbTestList.item(I, EmptyParam) as IHTMLOptionButtonElement;

    // Show a message if radiobutton is checked
    // Anzeigen, wenn dieser RadioButton ausgewählt
    if rbTest.Checked then
      ShowMessageFmt('Der RadioButton mit dem Wert %s' +
        ' ist ausgewählt!', [rbTest.Value]);
  end;

  // Set new values
  // Neuen Wert setzen
  for I := 0 to rbTestList.Length - 1 do
  begin
    // reference to the i. RadioButton
    // Referenz auf i. RadioButton
    rbTest := rbTestList.item(I, EmptyParam) as IHTMLOptionButtonElement;

    // check radiobutton with value 3.
    // Wir möchten den RadioButton mit dem Wert "3" aktivieren
    if rbTest.Value = '3' then
      rbTest.Checked := True;
  end;
end;

printed from
www.swissdelphicenter.ch
developers knowledge base